ghost-shell/flake.nix at master · thatwhichisdev/ghost-shell · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
{
  description = "A desktop shell built with iced, designed exclusively for Wayland and Niri.";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      fenix,
    }:
    let
      supportedSystems = [
        "aarch64-linux"
        "x86_64-linux"
      ];

      forEachSystem = nixpkgs.lib.genAttrs supportedSystems;

      pkgsFor = system: nixpkgs.legacyPackages.${system};

      rustToolchainFor =
        system:
        fenix.packages.${system}.fromToolchainFile {
          file = ./rust-toolchain.toml;
          sha256 = "sha256-33ovGhF2RVILEBnPLyPXVBG+NZ1DGgnijDGrl/9xAJQ=";
        };
    in
    {
      packages = forEachSystem (
        system:
        let
          pkgs = pkgsFor system;
          rustToolchain = rustToolchainFor system;

          ghost-shell = pkgs.callPackage ./nix/package.nix {
            inherit rustToolchain;
          };
        in
        {
          inherit ghost-shell;
          default = ghost-shell;
        }
      );

      devShells = forEachSystem (
        system:
        let
          pkgs = pkgsFor system;
          rustToolchain = rustToolchainFor system;
        in
        {
          default = import ./nix/dev-shell.nix {
            inherit pkgs rustToolchain;
          };
        }
      );

      homeManagerModules = rec {
        ghost-shell = import ./nix/module.nix { inherit self; };
        default = ghost-shell;
      };

      nixosModules.greeter = import ./nix/greeter-module.nix { inherit self; };

      formatter = forEachSystem (system: (pkgsFor system).nixfmt-tree);
    };
}