CMakeLists.txt

cmake_minimum_required(VERSION 3.20)
project(ThreadPool)

set(CMAKE_EXPORT_COMPILE_COMMANDS ON CACHE BOOL "" FORCE)

set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

option(ENABLE_TSAN "Build with ThreadSanitizer" OFF)

if(ENABLE_TSAN)
  add_compile_options(-Wall -Wextra -Wshadow -fsanitize=thread -g)
  add_link_options(-fsanitize=thread)
else()
  add_compile_options(-Wall -Wextra -Wshadow -fsanitize=address,undefined -g)
  add_link_options(-fsanitize=address,undefined)
endif()

find_package(Threads REQUIRED)

# --- library ---
add_library(threadpool src/ThreadPool.cpp src/Worker.cpp)
target_include_directories(threadpool PUBLIC include)
target_link_libraries(threadpool PUBLIC Threads::Threads)

# --- demo app ---
add_executable(threadpool_demo src/main.cpp)
target_link_libraries(threadpool_demo PRIVATE threadpool)

# --- tests ---
include(FetchContent)
FetchContent_Declare(
  googletest
  URL https://github.com/google/googletest/archive/refs/tags/v1.15.2.zip
)
set(gtest_force_shared_crt ON CACHE BOOL "" FORCE)
if(POLICY CMP0135)
  cmake_policy(SET CMP0135 NEW)
endif()
FetchContent_MakeAvailable(googletest)

enable_testing()
add_executable(unit_tests tests/threadpool_test.cpp)
target_link_libraries(unit_tests PRIVATE threadpool GTest::gtest_main)

include(GoogleTest)
gtest_discover_tests(unit_tests)