superstack-cli/flake.nix at main · siliconwitchery/superstack-cli · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
{
  description = "The Superstack command line interface";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-26.05";

  outputs = { self, nixpkgs }:
    let
      systems = [ "x86_64-linux" "aarch64-linux" "aarch64-darwin" "x86_64-darwin" ];
      forAllSystems = f: nixpkgs.lib.genAttrs systems
        (system: f (import nixpkgs { inherit system; }));
    in {
      packages = forAllSystems (pkgs: rec {
        superstack = pkgs.buildGoModule {
          pname = "superstack";

          version = builtins.head (
            builtins.match ".*const version = \"([^\"]+)\".*" (builtins.readFile ./main.go)
          );

          src = ./.;

          vendorHash = null;

          env.CGO_ENABLED = 0;

          ldflags = [
            "-s"
            "-w"
          ];

          postInstall = ''
            mv $out/bin/superstack-cli $out/bin/superstack
          '';

          meta = {
            description = "The Superstack command line interface";
            homepage = "https://github.com/siliconwitchery/superstack-cli";
            license = pkgs.lib.licenses.isc;
            mainProgram = "superstack";
            platforms = pkgs.lib.platforms.unix;
          };
        };

        default = superstack;
      });

      devShells = forAllSystems (pkgs: {
        default = pkgs.mkShell {
          packages = with pkgs; [
            go
            gopls
            git
            goreleaser
            shellcheck
          ];

          shellHook = ''
            export CGO_ENABLED=0
          '';
        };
      });
    };
}