[Utilities] add distance_to_set for PositiveSemidefiniteCone

Author: odow

src/Utilities/distance_to_set.jl

@@ -489,3 +489,39 @@ function distance_to_set(
     elements = [x[i] for i in eachindex(x) if !(i in pairs[k])]
     return LinearAlgebra.norm(elements, 2)
 end
+
+function _reshape(x::AbstractVector, set::MOI.PositiveSemidefiniteConeSquare)
+    n = MOI.side_dimension(set)
+    return reshape(x, (n, n))
+end
+
+function _reshape(x::AbstractVector, set::MOI.PositiveSemidefiniteConeTriangle)
+    n = MOI.side_dimension(set)
+    X = zeros(eltype(x), n, n)
+    k = 1
+    for i in 1:n
+        for j in 1:i
+            X[j,i] = X[i,j] = x[k]
+            k += 1
+        end
+    end
+    return LinearAlgebra.Symmetric(X)
+end
+
+function distance_to_set(
+    ::ProjectionUpperBoundDistance,
+    x::AbstractVector{T},
+    set::Union{
+        MOI.PositiveSemidefiniteConeSquare,
+        MOI.PositiveSemidefiniteConeTriangle,
+    },
+) where {T<:Real}
+    _check_dimension(x, set)
+    λ, U = LinearAlgebra.eigen(_reshape(x, set))
+    if minimum(λ) >= 0
+        return 0.0
+    end
+    λ_negative = LinearAlgebra.Diagonal(min.(zero(T), λ))
+    A = LinearAlgebra.Symmetric(U * λ_negative * U')
+    return LinearAlgebra.norm(A, 2)
+end

test/Utilities/distance_to_set.jl

@@ -308,6 +308,28 @@ function test_sos2()
     return
 end
 
+function test_positivesemidefiniteconesquare()
+    _test_set(
+        MOI.PositiveSemidefiniteConeSquare(2),
+        [1.0, 0.0, 0.0, 1.0] => 0.0,
+        [1.0, -1.0, -1.0, 1.0] => 0.0,
+        [1.0, -2.0, -2.0, 1.0] => 1.0;
+        mismatch = [1.0],
+    )
+    return
+end
+
+function test_positivesemidefiniteconetriangle()
+    _test_set(
+        MOI.PositiveSemidefiniteConeTriangle(2),
+        [1.0, 0.0, 1.0] => 0.0,
+        [1.0, -1.0, 1.0] => 0.0,
+        [1.0, -2.0, 1.0] => 1.0;
+        mismatch = [1.0],
+    )
+    return
+end
+
 end
 
 TestFeasibilityChecker.runtests()