Grammar railroad diagram

[mingodad]

I've just added MetaDSL grammar to https://mingodad.github.io/parsertl-playground/playground/ an Yacc/Lex compatible online editor/tester (select "MetaDSL parser" from "Examples" then click "Parse" to see a parse tree for the content in Input source).

My translation of MetaDSL is not complete and would be nice if the author could complete it and send a pull request or post it here.

I hope it can help develop/debug/document the MetaDSL grammar.

Any feedback is welcome !

And it can also generate an EBNF accepted by https://www.bottlecaps.de/rr/ui to generate a nice navigable railroad diagram (see bellow).

//
// EBNF to be viewd at https://www.bottlecaps.de/rr/ui
//
// Copy and paste this at https://www.bottlecaps.de/rr/ui in the 'Edit Grammar' tab
// then click the 'View Diagram' tab.
//

PROGRAM::=
	  STATEMENTS

STATEMENTS::=
	  STATEMENT
	| STATEMENTS SEP STATEMENT

STATEMENT::=
	  OPERATOR_STATEMENT_DESC_0

OPERATOR_STATEMENT_0::=
	  OPERATOR_STATEMENT_DESC_0

OPERATOR_STATEMENT_1::=
	  OPERATOR_STATEMENT_DESC_1

OPERATOR_STATEMENT_COLON::=
	  OPERATOR_STATEMENT_DESC_COLON

OPERATOR_STATEMENT_QUESTION_COLON::=
	  OPERATOR_STATEMENT_DESC_QUESTION_COLON

OPERATOR_STATEMENT_4::=
	  OPERATOR_STATEMENT_DESC_4

OPERATOR_STATEMENT_5::=
	  OPERATOR_STATEMENT_DESC_5

OPERATOR_STATEMENT_6::=
	  OPERATOR_STATEMENT_DESC_6

OPERATOR_STATEMENT_7::=
	  OPERATOR_STATEMENT_DESC_7

OPERATOR_STATEMENT_8::=
	  OPERATOR_STATEMENT_DESC_8

OPERATOR_STATEMENT_9::=
	  OPERATOR_STATEMENT_DESC_9

OPERATOR_STATEMENT_10::=
	  OPERATOR_STATEMENT_DESC_10

OPERATOR_STATEMENT_11::=
	  OPERATOR_STATEMENT_DESC_11

OPERATOR_STATEMENT_12::=
	  OPERATOR_STATEMENT_DESC_12

OPERATOR_STATEMENT_13::=
	  OPERATOR_STATEMENT_DESC_13

OPERATOR_STATEMENT_14::=
	  OPERATOR_STATEMENT_DESC_14

OPERATOR_STATEMENT_15::=
	  OPERATOR_STATEMENT_DESC_15

OPERATOR_STATEMENT_DESC_0::=
	  OPERATOR_STATEMENT_DESC_1
	| OPERATOR_STATEMENT_DESC_1 OP_TOKEN_0 OPERATOR_STATEMENT_0

OPERATOR_STATEMENT_DESC_1::=
	  OPERATOR_STATEMENT_DESC_2
	| OPERATOR_STATEMENT_DESC_2 OP_TOKEN_1 OPERATOR_STATEMENT_1

OPERATOR_STATEMENT_DESC_2::=
	  OPERATOR_STATEMENT_DESC_COLON
	| OPERATOR_STATEMENT_DESC_2 OP_TOKEN_2 OPERATOR_STATEMENT_COLON

OPERATOR_STATEMENT_DESC_COLON::=
	  OPERATOR_STATEMENT_DESC_QUESTION_COLON
	| OPERATOR_STATEMENT_DESC_COLON OP_TOKEN_COLON OPERATOR_STATEMENT_QUESTION_COLON

OPERATOR_STATEMENT_DESC_QUESTION_COLON::=
	  OPERATOR_STATEMENT_DESC_3
	| OPERATOR_STATEMENT_DESC_3 OP_TOKEN_QUESTION OPERATOR_STATEMENT_QUESTION_COLON OP_TOKEN_COLON OPERATOR_STATEMENT_QUESTION_COLON

OPERATOR_STATEMENT_DESC_3::=
	  OPERATOR_STATEMENT_DESC_4
	| OPERATOR_STATEMENT_DESC_3 OP_TOKEN_3 OPERATOR_STATEMENT_4

OPERATOR_STATEMENT_DESC_4::=
	  OPERATOR_STATEMENT_DESC_5
	| OPERATOR_STATEMENT_DESC_4 OP_TOKEN_4 OPERATOR_STATEMENT_5

OPERATOR_STATEMENT_DESC_5::=
	  OPERATOR_STATEMENT_DESC_6
	| OPERATOR_STATEMENT_DESC_5 OP_TOKEN_5 OPERATOR_STATEMENT_6

OPERATOR_STATEMENT_DESC_6::=
	  OPERATOR_STATEMENT_DESC_7
	| OPERATOR_STATEMENT_DESC_6 OP_TOKEN_6 OPERATOR_STATEMENT_7

OPERATOR_STATEMENT_DESC_7::=
	  OPERATOR_STATEMENT_DESC_8
	| OPERATOR_STATEMENT_DESC_7 OP_TOKEN_7 OPERATOR_STATEMENT_8

OPERATOR_STATEMENT_DESC_8::=
	  OPERATOR_STATEMENT_DESC_9
	| OPERATOR_STATEMENT_DESC_8 OP_TOKEN_8 OPERATOR_STATEMENT_9

OPERATOR_STATEMENT_DESC_9::=
	  OPERATOR_STATEMENT_DESC_10
	| OPERATOR_STATEMENT_DESC_9 OP_TOKEN_9 OPERATOR_STATEMENT_10

OPERATOR_STATEMENT_DESC_10::=
	  OPERATOR_STATEMENT_DESC_11
	| OPERATOR_STATEMENT_DESC_10 OP_TOKEN_10 OPERATOR_STATEMENT_11

OPERATOR_STATEMENT_DESC_11::=
	  OPERATOR_STATEMENT_DESC_12
	| OPERATOR_STATEMENT_DESC_11 OP_TOKEN_11 OPERATOR_STATEMENT_12

OPERATOR_STATEMENT_DESC_12::=
	  OPERATOR_STATEMENT_DESC_13
	| OPERATOR_STATEMENT_DESC_12 OP_TOKEN_12 OPERATOR_STATEMENT_13

OPERATOR_STATEMENT_DESC_13::=
	  OPERATOR_STATEMENT_DESC_14
	| OPERATOR_STATEMENT_DESC_13 OP_TOKEN_13 OPERATOR_STATEMENT_14

OPERATOR_STATEMENT_DESC_14::=
	  OPERATOR_STATEMENT_DESC_15
	| OPERATOR_STATEMENT_DESC_14 OP_TOKEN_14 OPERATOR_STATEMENT_15

OPERATOR_STATEMENT_DESC_15::=
	  FUNCTION_STATEMENT_DESC
	| OPERATOR_STATEMENT_DESC_15 OP_TOKEN_15 FUNCTION_STATEMENT

FUNCTION_STATEMENT::=
	  FUNCTION_STATEMENT_DESC

FUNCTION_STATEMENT_DESC::=
	  FUNCTION_CALLS

FUNCTION_CALLS::=
	  FUNCTION_EX_CALL_zom
	| FUNCTION_EX_CALL_SPECIAL FUNCTION_EX_CALL_zom

FUNCTION_EX_CALL_zom::=
	  /*%empty*/
	| FUNCTION_EX_CALL_zom FUNCTION_EX_CALL

FUNCTION_EX_CALL::=
	  FUNCTION_ID
	| FUNCTION_ID FUNCTION_PARAMS

FUNCTION_EX_CALL_SPECIAL::=
	  FUNCTION_PARAMS

FUNCTION_PARAMS::=
	  FUNCTION_PARAMS0
	| FUNCTION_PARAMS0 FUNCTION_PARAMS

FUNCTION_PARAMS0::=
	  '(' STATEMENTS ')'
	| '[' STATEMENTS ']'
	| "::" STATIC_MEMBER_DESC
	| '.' MEMBER_DESC
	| QUESTION_PERIOD MEMBER_DESC2
	| QUESTION_PARENTHESIS STATEMENTS ')'
	| QUESTION_BRACKET STATEMENTS ']'
	| QUESTION_BRACE STATEMENTS '}'
	| POINTER MEMBER_DESC3
	| PERIOD_STAR MEMBER_DESC4
	| QUESTION_PERIOD_STAR MEMBER_DESC5
	| POINTER_STAR MEMBER_DESC6
	| '{' STATEMENTS '}'
	| SCRIPT_CONTENT
	| BRACKET_COLON_BEGIN STATEMENTS BRACKET_COLON_END
	| PARENTHESIS_COLON_BEGIN STATEMENTS PARENTHESIS_COLON_END
	| ANGLE_BRACKET_COLON_BEGIN STATEMENTS ANGLE_BRACKET_COLON_END
	| BRACE_PERCENT_BEGIN STATEMENTS BRACE_PERCENT_END
	| BRACKET_PERCENT_BEGIN STATEMENTS BRACKET_PERCENT_END
	| PARENTHESIS_PERCENT_BEGIN STATEMENTS PARENTHESIS_PERCENT_END
	| ANGLE_BRACKET_PERCENT_BEGIN STATEMENTS ANGLE_BRACKET_PERCENT_END

STATIC_MEMBER_DESC::=
	  MEMBER_DESC

MEMBER_DESC::=
	  FUNCTION_ID
	| '(' STATEMENTS ')'
	| '[' STATEMENTS ']'
	| '{' STATEMENTS '}'

MEMBER_DESC2::=
	  FUNCTION_ID

MEMBER_DESC3::=
	  FUNCTION_ID

MEMBER_DESC4::=
	  FUNCTION_ID

MEMBER_DESC5::=
	  FUNCTION_ID

MEMBER_DESC6::=
	  FUNCTION_ID

FUNCTION_ID::=
	  IDENTIFIER
	| STRING
	| NUMBER
	| DOLLAR_STRING

SEP::=
	  ','
	| ';'

//Tokens

ANGLE_BRACKET_COLON_BEGIN ::= "<:"
ANGLE_BRACKET_COLON_END ::= ":>"
ANGLE_BRACKET_PERCENT_BEGIN ::= "<%"
ANGLE_BRACKET_PERCENT_END ::= "%>"
BRACE_PERCENT_BEGIN ::= "{%"
BRACE_PERCENT_END ::= "%}"
BRACKET_COLON_BEGIN ::= "[:"
BRACKET_COLON_END ::= ":]"
BRACKET_PERCENT_BEGIN ::= "[%"
BRACKET_PERCENT_END ::= "%]"
OP_TOKEN_0 ::= "="
OP_TOKEN_1 ::= "=>"|"<-"
OP_TOKEN_10 ::= "<<"|">>"|">>>"
OP_TOKEN_11 ::= "+"|"-"
OP_TOKEN_12 ::= "*"|"/"|"%"|".."
OP_TOKEN_13 ::= "++"|"--"|"~"|"!"
OP_TOKEN_3 ::= "||"|"??"
OP_TOKEN_4 ::= "&&"
OP_TOKEN_5 ::= "|"
OP_TOKEN_6 ::= "^"
OP_TOKEN_7 ::= "&"
OP_TOKEN_8 ::= "=="|"!="|"<=>"
OP_TOKEN_9 ::= "<="|">="|"<"|">"
OP_TOKEN_COLON ::= ":"
OP_TOKEN_QUESTION ::= "?"
PARENTHESIS_COLON_BEGIN ::= "(:"
PARENTHESIS_COLON_END ::= ":)"
PARENTHESIS_PERCENT_BEGIN ::= "(%"
PARENTHESIS_PERCENT_END ::= "%)"
PERIOD_STAR ::= ".*"
POINTER ::= "->"
POINTER_STAR ::= "->*"
QUESTION_BRACE ::= "?{"
QUESTION_BRACKET ::= "?["
QUESTION_PARENTHESIS ::= "?("
QUESTION_PERIOD ::= "?."
QUESTION_PERIOD_STAR ::= "?.*"

[dreamanlan]

MetaDSL uses a syntax analyzer generator PG (formerly called SLK) to generate syntax analysis. The grammar is LL(1) and eliminates left recursion. The original grammar is an extension of EBNF. I tried to rewrite the latest version in the style of yacc. The new version considers nullable operations, removes parentheses and member access syntax related to them, and adjusts the priority of conditional expressions to be compatible with C language operator rules.

But in the new version, I did some context-related recognition in lexical analysis to solve the conflict between the colon in conditional expressions and the ordinary colon operation, and the nullable operation is also a question mark or an exclamation mark, which will conflict with the question mark or logical operation in conditional expressions. It seems that the lexical part of yacc can't express it. I temporarily used -: -? -! to replace it.

[dreamanlan]

Below is the yacc syntax that passed the test on your link page (https://mingodad.github.io/parsertl-playground/playground/).

//From: https://github.com/dreamanlan/MetaDSL/blob/29e88dc3dca699d8236eed4fb63314624bf90155/DslParser/dsl.txt

%token ANGLE_BRACKET_COLON_BEGIN
%token ANGLE_BRACKET_COLON_END
%token ANGLE_BRACKET_PERCENT_BEGIN
%token ANGLE_BRACKET_PERCENT_END
%token BRACE_PERCENT_BEGIN
%token BRACE_PERCENT_END
%token BRACKET_COLON_BEGIN
%token BRACKET_COLON_END
%token BRACKET_PERCENT_BEGIN
%token BRACKET_PERCENT_END
%token DOLLAR_STRING
%token IDENTIFIER
%token NUMBER
%token OP_TOKEN_0
%token OP_TOKEN_1
%token OP_TOKEN_2
%token OP_TOKEN_3
%token OP_TOKEN_4
%token OP_TOKEN_5
%token OP_TOKEN_6
%token OP_TOKEN_7
%token OP_TOKEN_8
%token OP_TOKEN_9
%token OP_TOKEN_10
%token OP_TOKEN_11
%token OP_TOKEN_12
%token OP_TOKEN_13
%token OP_TOKEN_14
%token OP_TOKEN_15
%token OP_TOKEN_COLON
%token OP_TOKEN_QUESTION
%token OP_TOKEN_QUESTION_COLON
%token OP_TOKEN_NULLABLE
%token PARENTHESIS_COLON_BEGIN
%token PARENTHESIS_COLON_END
%token PARENTHESIS_PERCENT_BEGIN
%token PARENTHESIS_PERCENT_END
%token PERIOD_STAR
%token POINTER
%token POINTER_STAR
%token SCRIPT_CONTENT
%token STRING

%%

PROGRAM:
	STATEMENTS
	;

STATEMENTS:
	STATEMENT
	| STATEMENTS SEP STATEMENT
	;
	
STATEMENT:
	OPERATOR_STATEMENT_DESC_0	
	;

//OPERATOR_STATEMENT_0:
//	OPERATOR_STATEMENT_DESC_0

OPERATOR_STATEMENT_1:
	OPERATOR_STATEMENT_DESC_1
	;

OPERATOR_STATEMENT_2:
	OPERATOR_STATEMENT_DESC_2
	;

OPERATOR_STATEMENT_COLON:
	OPERATOR_STATEMENT_DESC_COLON
	;

//OPERATOR_STATEMENT_3:
//	OPERATOR_STATEMENT_DESC_3

OPERATOR_STATEMENT_4:
	OPERATOR_STATEMENT_DESC_4
	;

OPERATOR_STATEMENT_5:
	OPERATOR_STATEMENT_DESC_5
	;

OPERATOR_STATEMENT_6:
	OPERATOR_STATEMENT_DESC_6
	;

OPERATOR_STATEMENT_7:
	OPERATOR_STATEMENT_DESC_7
	;

OPERATOR_STATEMENT_8:
	OPERATOR_STATEMENT_DESC_8
	;

OPERATOR_STATEMENT_9:
	OPERATOR_STATEMENT_DESC_9
	;

OPERATOR_STATEMENT_10:
	OPERATOR_STATEMENT_DESC_10
	;

OPERATOR_STATEMENT_11:
	OPERATOR_STATEMENT_DESC_11
	;

OPERATOR_STATEMENT_12:
	OPERATOR_STATEMENT_DESC_12
	;

OPERATOR_STATEMENT_13:
	OPERATOR_STATEMENT_DESC_13
	;

OPERATOR_STATEMENT_14:
	OPERATOR_STATEMENT_DESC_14
	;

//OPERATOR_STATEMENT_15:
//	OPERATOR_STATEMENT_DESC_15
	
//Left Associative
OPERATOR_STATEMENT_DESC_0:
	OPERATOR_STATEMENT_DESC_1
	| OPERATOR_STATEMENT_DESC_0 OP_TOKEN_0 OPERATOR_STATEMENT_1
	;
	
//Right Associative (assignment, condition expression)
OPERATOR_STATEMENT_DESC_1:
	OPERATOR_STATEMENT_DESC_2
	| OPERATOR_STATEMENT_DESC_2 OPERATOR_STATEMENT_DESC_ASSIGNMENT_OR_QUESTION_COLON
	;

OPERATOR_STATEMENT_DESC_ASSIGNMENT_OR_QUESTION_COLON:
	OP_TOKEN_1 OPERATOR_STATEMENT_1
	| OP_TOKEN_QUESTION OPERATOR_STATEMENT_1 OP_TOKEN_QUESTION_COLON OPERATOR_STATEMENT_1
	;

//Right Associative (=>, <-)
OPERATOR_STATEMENT_DESC_2:
	OPERATOR_STATEMENT_DESC_COLON
	| OPERATOR_STATEMENT_DESC_COLON OP_TOKEN_2 OPERATOR_STATEMENT_2
	;
	
//Right Associative (type info)
OPERATOR_STATEMENT_DESC_COLON:
	OPERATOR_STATEMENT_DESC_3
	| OPERATOR_STATEMENT_DESC_3 OP_TOKEN_COLON OPERATOR_STATEMENT_COLON
	;
	
//Left Associative
OPERATOR_STATEMENT_DESC_3:
	OPERATOR_STATEMENT_DESC_4
	| OPERATOR_STATEMENT_DESC_3 OP_TOKEN_3 OPERATOR_STATEMENT_4
	;
	
//Left Associative
OPERATOR_STATEMENT_DESC_4:
	OPERATOR_STATEMENT_DESC_5
	| OPERATOR_STATEMENT_DESC_4 OP_TOKEN_4 OPERATOR_STATEMENT_5
	;
	
//Left Associative
OPERATOR_STATEMENT_DESC_5:
	OPERATOR_STATEMENT_DESC_6
	| OPERATOR_STATEMENT_DESC_5 OP_TOKEN_5 OPERATOR_STATEMENT_6
	;
	
//Left Associative
OPERATOR_STATEMENT_DESC_6:
	OPERATOR_STATEMENT_DESC_7
	| OPERATOR_STATEMENT_DESC_6 OP_TOKEN_6 OPERATOR_STATEMENT_7
	;
	
//Left Associative
OPERATOR_STATEMENT_DESC_7:
	OPERATOR_STATEMENT_DESC_8
	| OPERATOR_STATEMENT_DESC_7 OP_TOKEN_7 OPERATOR_STATEMENT_8
	;
	
//Left Associative
OPERATOR_STATEMENT_DESC_8:
	OPERATOR_STATEMENT_DESC_9
	| OPERATOR_STATEMENT_DESC_8 OP_TOKEN_8 OPERATOR_STATEMENT_9
	;
	
//Left Associative
OPERATOR_STATEMENT_DESC_9:
	OPERATOR_STATEMENT_DESC_10
	| OPERATOR_STATEMENT_DESC_9 OP_TOKEN_9 OPERATOR_STATEMENT_10
	;
	
//Left Associative
OPERATOR_STATEMENT_DESC_10:
	OPERATOR_STATEMENT_DESC_11
	| OPERATOR_STATEMENT_DESC_10 OP_TOKEN_10 OPERATOR_STATEMENT_11
	;
	
//Left Associative
OPERATOR_STATEMENT_DESC_11:
	OPERATOR_STATEMENT_DESC_12
	| OPERATOR_STATEMENT_DESC_11 OP_TOKEN_11 OPERATOR_STATEMENT_12
	;
	
//Left Associative
OPERATOR_STATEMENT_DESC_12:
	OPERATOR_STATEMENT_DESC_13
	| OPERATOR_STATEMENT_DESC_12 OP_TOKEN_12 OPERATOR_STATEMENT_13
	;
	
//Left Associative
OPERATOR_STATEMENT_DESC_13:
	OPERATOR_STATEMENT_DESC_14
	| OPERATOR_STATEMENT_DESC_13 OP_TOKEN_13 OPERATOR_STATEMENT_14
	;
	
//Right Associative (unary operator)
OPERATOR_STATEMENT_DESC_14:
	OPERATOR_STATEMENT_DESC_15
	| OPERATOR_STATEMENT_DESC_15 OP_TOKEN_14 OPERATOR_STATEMENT_14
	;
	
//Left Associative (member operator like)
OPERATOR_STATEMENT_DESC_15:
	FUNCTION_STATEMENT_DESC
	| OPERATOR_STATEMENT_DESC_15 OP_TOKEN_15 FUNCTION_STATEMENT
	;
		
FUNCTION_STATEMENT:
	FUNCTION_STATEMENT_DESC
	;

FUNCTION_STATEMENT_DESC:
	FUNCTION_CALLS
	;
	
FUNCTION_CALLS:
	FUNCTION_EX_CALL_zom
	| FUNCTION_PARAMS FUNCTION_EX_CALL_zom
	;
	
FUNCTION_EX_CALL_zom:
	/*empty*/
	| FUNCTION_EX_CALL_zom FUNCTION_EX_CALL
	;
	
FUNCTION_EX_CALL:
	FUNCTION_ID
	| FUNCTION_ID NULLABLE_FUNCTION_PARAMS
	;
	
NULLABLE_FUNCTION_PARAMS:
	OP_TOKEN_NULLABLE FUNCTION_PARAMS
	| FUNCTION_PARAMS
	;

FUNCTION_PARAMS: 
	PARENTHESIS_PARAMS
	| MEMBER
	;
	
PARENTHESIS_PARAMS:
	PARENTHESIS_PARAMS0
	| PARENTHESIS_PARAMS0 NULLABLE_FUNCTION_PARAMS
	;

PARENTHESIS_PARAMS0:
	'(' STATEMENTS ')'
	| '[' STATEMENTS ']'
	| '{' STATEMENTS '}'
	| SCRIPT_CONTENT
	| BRACKET_COLON_BEGIN STATEMENTS BRACKET_COLON_END
	| PARENTHESIS_COLON_BEGIN STATEMENTS PARENTHESIS_COLON_END
	| ANGLE_BRACKET_COLON_BEGIN STATEMENTS ANGLE_BRACKET_COLON_END
	| BRACE_PERCENT_BEGIN STATEMENTS BRACE_PERCENT_END
	| BRACKET_PERCENT_BEGIN STATEMENTS BRACKET_PERCENT_END
	| PARENTHESIS_PERCENT_BEGIN STATEMENTS PARENTHESIS_PERCENT_END
	| ANGLE_BRACKET_PERCENT_BEGIN STATEMENTS ANGLE_BRACKET_PERCENT_END
	;
	
MEMBER:
	MEMBER0
	| MEMBER0 NULLABLE_FUNCTION_PARAMS
	;

MEMBER0:
	"::" MEMBER_PARAM
	| '.' MEMBER_PARAM
	| POINTER MEMBER_PARAM
	| PERIOD_STAR MEMBER_PARAM
	| POINTER_STAR MEMBER_PARAM
	;

MEMBER_PARAM:
	FUNCTION_ID
	| '(' STATEMENTS ')'
	| '[' STATEMENTS ']'
	| '{' STATEMENTS '}'
	| SCRIPT_CONTENT
	| BRACKET_COLON_BEGIN STATEMENTS BRACKET_COLON_END
	| PARENTHESIS_COLON_BEGIN STATEMENTS PARENTHESIS_COLON_END
	| ANGLE_BRACKET_COLON_BEGIN STATEMENTS ANGLE_BRACKET_COLON_END
	| BRACE_PERCENT_BEGIN STATEMENTS BRACE_PERCENT_END
	| BRACKET_PERCENT_BEGIN STATEMENTS BRACKET_PERCENT_END
	| PARENTHESIS_PERCENT_BEGIN STATEMENTS PARENTHESIS_PERCENT_END
	| ANGLE_BRACKET_PERCENT_BEGIN STATEMENTS ANGLE_BRACKET_PERCENT_END
	;

FUNCTION_ID:
	IDENTIFIER
	| STRING
	| NUMBER
	| DOLLAR_STRING
	;
	
SEP:
	','
	| ';'
	;

%%

operators [~`!%^&*\-+=|:<>?/]

%%

[\n\r\t ]+	skip()
"#".*	skip()
"//".*		skip()
"/*"(?s:.)*?"*/"	skip()

"("	'('
")"	')'
"["	'['
"]"	']'
"::"	"::"
"."	'.'
"}"	'}'
"{"	'{'
","	','
";"	';'

"<:"	ANGLE_BRACKET_COLON_BEGIN
":>"	ANGLE_BRACKET_COLON_END
"<%"	ANGLE_BRACKET_PERCENT_BEGIN
"%>"	ANGLE_BRACKET_PERCENT_END
"{%"	BRACE_PERCENT_BEGIN
"%}"	BRACE_PERCENT_END
"[:"	BRACKET_COLON_BEGIN
":]"	BRACKET_COLON_END
"[%"	BRACKET_PERCENT_BEGIN
"%]"	BRACKET_PERCENT_END
"`" OP_TOKEN_0
"="	OP_TOKEN_1
"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="	OP_TOKEN_1
">>="|"<<="	OP_TOKEN_1
">>>="	OP_TOKEN_1
"=>"|"<-"	OP_TOKEN_2
"||"|"??"	OP_TOKEN_4
"&&"	OP_TOKEN_5
"|"	OP_TOKEN_6
"^"	OP_TOKEN_7
"&"	OP_TOKEN_8
"=="|"!="|"<=>"	OP_TOKEN_9
"<="|">="|"<"|">"	OP_TOKEN_10
"<<"|">>>"|">>"	OP_TOKEN_11
"+"|"-"	OP_TOKEN_12
"*"|"/"|"%"|".."	OP_TOKEN_13
"++"|"--"|"~"|"!"	OP_TOKEN_14
OP_TOKEN_15	OP_TOKEN_15
":"	OP_TOKEN_COLON
"?"	OP_TOKEN_QUESTION
"-:" OP_TOKEN_QUESTION_COLON	//conflict with OP_TOKEN_COLON
"-?" OP_TOKEN_NULLABLE			//conflict with OP_TOKEN_QUESTION
"-!" OP_TOKEN_NULLABLE			//conflict with OP_TOKEN_14
"(:"	PARENTHESIS_COLON_BEGIN
":)"	PARENTHESIS_COLON_END
"(%"	PARENTHESIS_PERCENT_BEGIN
"%)"	PARENTHESIS_PERCENT_END
".*"	PERIOD_STAR
"->"	POINTER
"->*"	POINTER_STAR

"{:"(?s:.)*?":}"	SCRIPT_CONTENT

DOLLAR_STRING   DOLLAR_STRING
\"(\\.|[^"\n\r\\])+\"	STRING
'(\\.|[^'\n\r\\])+'	STRING
[0-9]+	NUMBER
[\$@A-Za-z_][A-Za-z0-9_]*	IDENTIFIER
\`[\$@A-Za-z_][A-Za-z0-9_]*	OP_TOKEN_3

%%

[dreamanlan]

The corresponding test code is as follows: use '-:', '-?', '-!' (for https://mingodad.github.io/parsertl-playground/playground/)

skill(kkk )
{
	section(80 )
	{
		ok("		yyyy yyyy yyyy" );
		ok("yyyy yyyy yyyy" );
		a = "yyyy yyyy yyyy";
		attr(1005 ) = (attr(1001 ) + attr(1002 ) * attr(2001 ) ) * (1 + attr(1003 ) ) + attr(1004 );
		a > b ? 1 -: 0
		a + b * c;
		test();
		test(123  345  678 );
	};
	script(sss )
	{:
		ok, this is a test, "yeah!!!";
	:};
	script(ttt : string  tt2 : int )
	{: abcd :};
	(:attr :)
	script(ttt )
	{::}
	[:attr :]
	script(ttt )
	{:
  abcdef;
  defg;
	:}
	a = "b";
	a = " abcd ";
	template<:a  b  c :>class A
	a::b ::c ;
	a::b (abcd );
	a :: (abcd );
	b :: [abcd ];
	c ::
	{
		abcd
	};
	{%abcd %};
	[%abcd %];
	(%abcd %);
	<%abcd %>;
	a -> {};
	a -> [];
	a -> ();
	a->*b ;
	a->func ();
	a-?.*p ();
	a-?.b ;
	a.b ;
	a.*p ();
};
skill(ttt : string  tt2 : int )
{
};
namespace(GamePlay );
import(Brace.Base .Io  );
interace(ICurly )
{
	Exec(str : string )int
};
class(Player )extends(Character )
implements(ICurly )
{
	public
	{
		Entry(str : string )
		int
		{
			print(str );
			return <- (0 );
		}
		Exec(str : string )
		int
		{
			return <- (atoi(str ) );
		}
	};
	private
	{
		m_Abc : int;
	};
}
externsion(ifndef )
extends(Statement )
{
}
main()
int
{
	@ct += 2;
	echo("@ct:"  @ct );
	echo("inc:"  ++ @ct );
	echo("dec:"  -- @ct );
	echo("positive:"  + @ct );
	echo("negative:"  - @ct );
	return <- a * b + 4;
}

[dreamanlan]

The following is for https://www.bottlecaps.de/rr/ui

PROGRAM::=
	STATEMENTS

STATEMENTS::=
	STATEMENT
	| STATEMENTS SEP STATEMENT
	
STATEMENT::=
	OPERATOR_STATEMENT_DESC_0

//OPERATOR_STATEMENT_0::=
//	OPERATOR_STATEMENT_DESC_0

OPERATOR_STATEMENT_1::=
	OPERATOR_STATEMENT_DESC_1

OPERATOR_STATEMENT_2::=
	OPERATOR_STATEMENT_DESC_2

OPERATOR_STATEMENT_COLON::=
	OPERATOR_STATEMENT_DESC_COLON

//OPERATOR_STATEMENT_3::=
//	OPERATOR_STATEMENT_DESC_3

OPERATOR_STATEMENT_4::=
	OPERATOR_STATEMENT_DESC_4

OPERATOR_STATEMENT_5::=
	OPERATOR_STATEMENT_DESC_5

OPERATOR_STATEMENT_6::=
	OPERATOR_STATEMENT_DESC_6

OPERATOR_STATEMENT_7::=
	OPERATOR_STATEMENT_DESC_7

OPERATOR_STATEMENT_8::=
	OPERATOR_STATEMENT_DESC_8

OPERATOR_STATEMENT_9::=
	OPERATOR_STATEMENT_DESC_9

OPERATOR_STATEMENT_10::=
	OPERATOR_STATEMENT_DESC_10

OPERATOR_STATEMENT_11::=
	OPERATOR_STATEMENT_DESC_11

OPERATOR_STATEMENT_12::=
	OPERATOR_STATEMENT_DESC_12

OPERATOR_STATEMENT_13::=
	OPERATOR_STATEMENT_DESC_13

OPERATOR_STATEMENT_14::=
	OPERATOR_STATEMENT_DESC_14

//OPERATOR_STATEMENT_15::=
//	OPERATOR_STATEMENT_DESC_15
	
//Left Associative
OPERATOR_STATEMENT_DESC_0::=
	OPERATOR_STATEMENT_DESC_1
	| OPERATOR_STATEMENT_DESC_0 OP_TOKEN_0 OPERATOR_STATEMENT_1
	
//Right Associative (assignment, condition expression)
OPERATOR_STATEMENT_DESC_1::=
	OPERATOR_STATEMENT_DESC_2
	| OPERATOR_STATEMENT_DESC_2 OPERATOR_STATEMENT_DESC_ASSIGNMENT_OR_QUESTION_COLON

OPERATOR_STATEMENT_DESC_ASSIGNMENT_OR_QUESTION_COLON::=
	OP_TOKEN_1 OPERATOR_STATEMENT_1
	| OP_TOKEN_QUESTION OPERATOR_STATEMENT_1 OP_TOKEN_QUESTION_COLON OPERATOR_STATEMENT_1

//Right Associative (=>, <-)
OPERATOR_STATEMENT_DESC_2::=
	OPERATOR_STATEMENT_DESC_COLON
	| OPERATOR_STATEMENT_DESC_COLON OP_TOKEN_2 OPERATOR_STATEMENT_2
	
//Right Associative (type info)
OPERATOR_STATEMENT_DESC_COLON::=
	OPERATOR_STATEMENT_DESC_3
	| OPERATOR_STATEMENT_DESC_3 OP_TOKEN_COLON OPERATOR_STATEMENT_COLON
	
//Left Associative
OPERATOR_STATEMENT_DESC_3::=
	OPERATOR_STATEMENT_DESC_4
	| OPERATOR_STATEMENT_DESC_3 OP_TOKEN_3 OPERATOR_STATEMENT_4
	
//Left Associative
OPERATOR_STATEMENT_DESC_4::=
	OPERATOR_STATEMENT_DESC_5
	| OPERATOR_STATEMENT_DESC_4 OP_TOKEN_4 OPERATOR_STATEMENT_5
	
//Left Associative
OPERATOR_STATEMENT_DESC_5::=
	OPERATOR_STATEMENT_DESC_6
	| OPERATOR_STATEMENT_DESC_5 OP_TOKEN_5 OPERATOR_STATEMENT_6
	
//Left Associative
OPERATOR_STATEMENT_DESC_6::=
	OPERATOR_STATEMENT_DESC_7
	| OPERATOR_STATEMENT_DESC_6 OP_TOKEN_6 OPERATOR_STATEMENT_7
	
//Left Associative
OPERATOR_STATEMENT_DESC_7::=
	OPERATOR_STATEMENT_DESC_8
	| OPERATOR_STATEMENT_DESC_7 OP_TOKEN_7 OPERATOR_STATEMENT_8
	
//Left Associative
OPERATOR_STATEMENT_DESC_8::=
	OPERATOR_STATEMENT_DESC_9
	| OPERATOR_STATEMENT_DESC_8 OP_TOKEN_8 OPERATOR_STATEMENT_9
	
//Left Associative
OPERATOR_STATEMENT_DESC_9::=
	OPERATOR_STATEMENT_DESC_10
	| OPERATOR_STATEMENT_DESC_9 OP_TOKEN_9 OPERATOR_STATEMENT_10
	
//Left Associative
OPERATOR_STATEMENT_DESC_10::=
	OPERATOR_STATEMENT_DESC_11
	| OPERATOR_STATEMENT_DESC_10 OP_TOKEN_10 OPERATOR_STATEMENT_11
	
//Left Associative
OPERATOR_STATEMENT_DESC_11::=
	OPERATOR_STATEMENT_DESC_12
	| OPERATOR_STATEMENT_DESC_11 OP_TOKEN_11 OPERATOR_STATEMENT_12
	
//Left Associative
OPERATOR_STATEMENT_DESC_12::=
	OPERATOR_STATEMENT_DESC_13
	| OPERATOR_STATEMENT_DESC_12 OP_TOKEN_12 OPERATOR_STATEMENT_13
	
//Left Associative
OPERATOR_STATEMENT_DESC_13::=
	OPERATOR_STATEMENT_DESC_14
	| OPERATOR_STATEMENT_DESC_13 OP_TOKEN_13 OPERATOR_STATEMENT_14
	
//Right Associative (unary operator)
OPERATOR_STATEMENT_DESC_14::=
	OPERATOR_STATEMENT_DESC_15
	| OPERATOR_STATEMENT_DESC_15 OP_TOKEN_14 OPERATOR_STATEMENT_14
	
//Left Associative (member operator like)
OPERATOR_STATEMENT_DESC_15::=
	FUNCTION_STATEMENT_DESC
	| OPERATOR_STATEMENT_DESC_15 OP_TOKEN_15 FUNCTION_STATEMENT
		
FUNCTION_STATEMENT::=
	FUNCTION_STATEMENT_DESC

FUNCTION_STATEMENT_DESC::=
	FUNCTION_CALLS
	
FUNCTION_CALLS::=
	FUNCTION_EX_CALL_zom
	| FUNCTION_PARAMS FUNCTION_EX_CALL_zom
	
FUNCTION_EX_CALL_zom::=
	/*empty*/
	| FUNCTION_EX_CALL_zom FUNCTION_EX_CALL
	
FUNCTION_EX_CALL::=
	FUNCTION_ID
	| FUNCTION_ID NULLABLE_FUNCTION_PARAMS
	
NULLABLE_FUNCTION_PARAMS::=
	OP_TOKEN_NULLABLE FUNCTION_PARAMS
	| FUNCTION_PARAMS

FUNCTION_PARAMS::= 
	PARENTHESIS_PARAMS
	| MEMBER
	
PARENTHESIS_PARAMS::=
	PARENTHESIS_PARAMS0
	| PARENTHESIS_PARAMS0 NULLABLE_FUNCTION_PARAMS

PARENTHESIS_PARAMS0::=
	'(' STATEMENTS ')'
	| '[' STATEMENTS ']'
	| '{' STATEMENTS '}'
	| SCRIPT_CONTENT
	| BRACKET_COLON_BEGIN STATEMENTS BRACKET_COLON_END
	| PARENTHESIS_COLON_BEGIN STATEMENTS PARENTHESIS_COLON_END
	| ANGLE_BRACKET_COLON_BEGIN STATEMENTS ANGLE_BRACKET_COLON_END
	| BRACE_PERCENT_BEGIN STATEMENTS BRACE_PERCENT_END
	| BRACKET_PERCENT_BEGIN STATEMENTS BRACKET_PERCENT_END
	| PARENTHESIS_PERCENT_BEGIN STATEMENTS PARENTHESIS_PERCENT_END
	| ANGLE_BRACKET_PERCENT_BEGIN STATEMENTS ANGLE_BRACKET_PERCENT_END
	
MEMBER::=
	MEMBER0
	| MEMBER0 NULLABLE_FUNCTION_PARAMS

MEMBER0::=
	"::" MEMBER_PARAM
	| '.' MEMBER_PARAM
	| POINTER MEMBER_PARAM
	| PERIOD_STAR MEMBER_PARAM
	| POINTER_STAR MEMBER_PARAM

MEMBER_PARAM::=
	FUNCTION_ID
	| '(' STATEMENTS ')'
	| '[' STATEMENTS ']'
	| '{' STATEMENTS '}'
	| SCRIPT_CONTENT
	| BRACKET_COLON_BEGIN STATEMENTS BRACKET_COLON_END
	| PARENTHESIS_COLON_BEGIN STATEMENTS PARENTHESIS_COLON_END
	| ANGLE_BRACKET_COLON_BEGIN STATEMENTS ANGLE_BRACKET_COLON_END
	| BRACE_PERCENT_BEGIN STATEMENTS BRACE_PERCENT_END
	| BRACKET_PERCENT_BEGIN STATEMENTS BRACKET_PERCENT_END
	| PARENTHESIS_PERCENT_BEGIN STATEMENTS PARENTHESIS_PERCENT_END
	| ANGLE_BRACKET_PERCENT_BEGIN STATEMENTS ANGLE_BRACKET_PERCENT_END

FUNCTION_ID::=
	IDENTIFIER
	| STRING
	| NUMBER
	| DOLLAR_STRING
	
SEP::=
	','
	| ';'

//Tokens

ANGLE_BRACKET_COLON_BEGIN ::= "<:"
ANGLE_BRACKET_COLON_END ::= ":>"
ANGLE_BRACKET_PERCENT_BEGIN ::= "<%"
ANGLE_BRACKET_PERCENT_END ::= "%>"
BRACE_PERCENT_BEGIN ::= "{%"
BRACE_PERCENT_END ::= "%}"
BRACKET_COLON_BEGIN ::= "[:"
BRACKET_COLON_END ::= ":]"
BRACKET_PERCENT_BEGIN ::= "[%"
BRACKET_PERCENT_END ::= "%]"
OP_TOKEN_0 ::= "`"
OP_TOKEN_1 ::= "="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|">>="|"<<="|">>>="
OP_TOKEN_2 ::= "=>"|"<-"
OP_TOKEN_4 ::= "||"|"??"
OP_TOKEN_5 ::= "&&"
OP_TOKEN_6 ::= "|"
OP_TOKEN_7 ::= "^"
OP_TOKEN_8 ::= "&"
OP_TOKEN_9 ::= "=="|"!="|"<=>"
OP_TOKEN_10 ::= "<="|">="|"<"|">"
OP_TOKEN_11 ::= "<<"|">>"|">>>"
OP_TOKEN_12 ::= "+"|"-"
OP_TOKEN_13 ::= "*"|"/"|"%"|".."
OP_TOKEN_14 ::= "++"|"--"|"~"|"!"
OP_TOKEN_COLON ::= ":"
OP_TOKEN_QUESTION ::= "?"
OP_TOKEN_QUESTION_COLON ::= "-:"
OP_TOKEN_NULLABLE ::= "-?"|"-!"
PARENTHESIS_COLON_BEGIN ::= "(:"
PARENTHESIS_COLON_END ::= ":)"
PARENTHESIS_PERCENT_BEGIN ::= "(%"
PARENTHESIS_PERCENT_END ::= "%)"
PERIOD_STAR ::= ".*"
POINTER ::= "->"
POINTER_STAR ::= "->*"

[mingodad]

Hello @dreamanlan thank you for your fixes !
I've just updated it on https://mingodad.github.io/parsertl-playground/playground/ .
You are the first one that I know that uses SLK it's an intriguing parser generator and I don't know why the author only distributes it in uglyfied source .