cryptad/settings.gradle.kts at develop · crypta-network/cryptad · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
pluginManagement {
  val toml = file("gradle/libs.versions.toml").readText()
  fun version(key: String): String {
    val pattern = Regex("""^\s*${Regex.escape(key)}\s*=\s*\"([^\"]+)\"""", RegexOption.MULTILINE)
    return pattern.find(toml)?.groupValues?.get(1)
      ?: error("Version '$key' not found in libs.versions.toml")
  }

  repositories {
    gradlePluginPortal()
    mavenCentral()
  }
  plugins {
    id("org.gradle.toolchains.foojay-resolver-convention") version version("foojayResolver")
  }
}

// Configure repositories for Java toolchain auto-provisioning (fixes Gradle 10 deprecation)
plugins { id("org.gradle.toolchains.foojay-resolver-convention") }

dependencyResolutionManagement {
  repositoriesMode.set(RepositoriesMode.PREFER_PROJECT)
  repositories {
    mavenCentral {
      metadataSources {
        mavenPom()
        artifact()
        ignoreGradleMetadataRedirection()
      }
    }
  }
}

rootProject.name = "cryptad"

include(
  ":apps:queue-manager",
  ":apps:publisher",
  ":apps:feed-reader",
  ":apps:profile-publisher",
  ":apps:social-inbox",
  ":apps:site-publisher",
  ":apps:trust-graph",
  ":apps:mail-prototype",
  ":platform-design-system",
  ":platform-appvault",
  ":platform-appdist",
  ":platform-devtools",
  ":platform-app-ui",
  ":platform-appcatalog",
  ":platform-trustgraph",
  ":foundation-support",
  ":foundation-store",
  ":foundation-store-contracts",
  ":foundation-crypto-keys",
  ":interop-wire",
  ":foundation-config",
  ":foundation-fs",
  ":foundation-compat",
  ":kernel-content",
  ":kernel-transport",
  ":kernel-routing",
  ":runtime-spi",
  ":platform-api",
  ":platform-apphost",
  ":platform-sdk-js",
  ":platform-web-shell",
  ":runtime-alerts",
  ":runtime-node",
  ":adapter-fcp",
  ":bridge-fcp-runtime",
  ":bridge-http-runtime",
  ":adapter-http-legacy-admin",
  ":adapter-http-legacy-browse",
  ":thirdparty-onion",
  ":thirdparty-legacy",
  ":launcher-desktop",
)

// Gradle 9: Use an included build for convention plugins instead of buildSrc
includeBuild("build-logic")