custom-install/package.nix at python-package · ahrib/custom-install · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
{
  lib,
  pkgs,
  python,
  callPackage,
  buildPythonApplication,
  fetchPypi,
  pyctr,
  pycryptodomex,
  pypng,
  tkinter,
  setuptools,
  events,
  stdenv,
  save3ds,

  withGUI ? true,
}:

let
  save3ds_no_fuse = save3ds.override { withFUSE = false; };
in
buildPythonApplication rec {
  pname = "custominstall";
  version = "2.1";
  pyproject = true;

  src = builtins.path {
    path = ./.;
    name = "custominstall";
    filter =
      path: type:
      !(builtins.elem (baseNameOf path) [
        "build"
        "dist"
        "localtest"
        "__pycache__"
        "v"
        ".git"
        "_build"
        "custominstall.egg-info"
      ]);
  };

  doCheck = false;

  build-system = [ setuptools ];

  propagatedBuildInputs =
    [
      pyctr
      pycryptodomex
      setuptools
      events
    ]
    ++ lib.optionals (withGUI) [
      tkinter
    ];

  makeWrapperArgs = [ "--set CUSTOM_INSTALL_SAVE3DS_PATH ${save3ds_no_fuse}/bin/save3ds_fuse" ];

  preFixup = ''
    rm -r $out/lib/${python.libPrefix}/site-packages/custominstall/bin
    ${lib.optionalString (!withGUI) "rm $out/bin/custominstall-gui"}
  '';

  meta = with lib; {
    description = "Installs a title directly to an SD card for the Nintendo 3DS";
    homepage = "https://github.com/ihaveamac/custom-install";
    license = licenses.mit;
    platforms = platforms.unix;
    mainProgram = "custominstall";
  };
}