Merge pull request #88 from dav-og/feature/moordyn-coupling

Add MoorDyn mooring coupling with real-time tension visualization

Author: dav-og

.gitignore

@@ -42,6 +42,10 @@ doc/user/_verification/demos/sphere_decay/*.png
 doc/user/_verification/demos/sphere_decay/*.hires.png
 _build/
 
+# MoorDyn workaround (copied at configure time, see CMakeLists.txt)
+/cmake/MoorDynConfig.cmake
+/LICENSE.txt
+
 # General
 build/
 demos/F3OF/f3of/

.gitmodules

@@ -0,0 +1,3 @@
+[submodule "extern/MoorDyn"]
+	path = extern/MoorDyn
+	url = https://github.com/FloatingArrayDesign/MoorDyn.git

CMakeLists.txt

@@ -52,10 +52,10 @@ configure_file(${CMAKE_SOURCE_DIR}/cmake/version.h.in
 # Add the cmake folder so the FindSphinx module is found
 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/cmake" ${CMAKE_MODULE_PATH})
 
-# Deterministic dependency discovery (avoid ambient PATH/registry drift)
+# Prefer config-mode package discovery (finds vcpkg *-config.cmake files
+# instead of CMake's built-in Find*.cmake modules which may not understand vcpkg).
 set(CMAKE_FIND_PACKAGE_PREFER_CONFIG ON)
 set(CMAKE_FIND_USE_PACKAGE_REGISTRY OFF)
-set(CMAKE_FIND_USE_SYSTEM_ENVIRONMENT_PATH OFF)
 
 # Force Release by default so CI builds are optimized and users get good performance
 if(NOT DEFINED HYDROCHRONO_DEFAULT_BUILD_TYPE)
@@ -79,6 +79,7 @@ option(HYDROCHRONO_ENABLE_IRRLICHT "Enable Irrlicht visualization library" OFF)
 option(HYDROCHRONO_ENABLE_VSG "Enable VSG visualization library" OFF)
 option(HYDROCHRONO_ENABLE_DEMOS "Enable demo executables" OFF)
 option(HYDROCHRONO_ENABLE_YAML_RUNNER "Enable YAML-based CLI runner" OFF)
+option(HYDROCHRONO_ENABLE_MOORDYN "Enable MoorDyn mooring coupling" OFF)
 
 # ===============================================================================
 # ------ Build setup ------------------------------------------------------------
@@ -167,10 +168,36 @@ if(NOT Chrono_DIR)
     return()
 endif()
 
+# Pre-load HDF5 targets so the shims below are only created when genuinely
+# needed (i.e., when HDF5 config-mode doesn't provide hdf5_tools).
+# Without this, installers that define all HDF5 targets as a batch
+# (e.g., HDF Group installer) error out on the partial pre-definition.
+find_package(HDF5 CONFIG QUIET)
+
+# Chrono's export file may reference hdf5::hdf5_tools-{shared,static} which is
+# absent from some HDF5 installations (e.g., vcpkg). Provide empty shims so
+# ChronoTargets.cmake loads without errors. Must be created BEFORE find_package(Chrono).
+if(NOT TARGET hdf5::hdf5_tools-shared)
+    add_library(hdf5::hdf5_tools-shared INTERFACE IMPORTED)
+endif()
+if(NOT TARGET hdf5::hdf5_tools-static)
+    add_library(hdf5::hdf5_tools-static INTERFACE IMPORTED)
+endif()
+
 find_package(Chrono
              CONFIG REQUIRED
              COMPONENTS Parsers)
 
+# If the early HDF5 find failed but Chrono has now set HDF5_DIR, retry.
+# The early find may have cached HDF5_DIR-NOTFOUND, blocking Chrono's
+# non-FORCE cache set.  Clear it and retry with the Chrono-provided path.
+if(NOT HDF5_FOUND AND DEFINED CACHE{HDF5_DIR})
+    if("${HDF5_DIR}" MATCHES "NOTFOUND")
+        unset(HDF5_DIR CACHE)
+        find_package(HDF5 CONFIG QUIET)
+    endif()
+endif()
+
 message(STATUS "----\n")
 
 message(STATUS "Chrono targets: ${CHRONO_TARGETS}")
@@ -203,6 +230,20 @@ else()
   message(STATUS "Set C++ standard to: ${HC_CXX_STANDARD}")
 endif()
 
+# Detect whether Chrono has the newer ChLoadHydrodynamics API.
+# If not, fall back to HydroChrono's legacy added-mass implementation.
+set(CHRONO_HAS_LOAD_HYDRODYNAMICS FALSE)
+get_target_property(_chrono_inc_dirs Chrono::Chrono_core INTERFACE_INCLUDE_DIRECTORIES)
+foreach(_dir ${_chrono_inc_dirs})
+    if(EXISTS "${_dir}/chrono/physics/ChLoadHydrodynamics.h")
+        set(CHRONO_HAS_LOAD_HYDRODYNAMICS TRUE)
+        break()
+    endif()
+endforeach()
+if(NOT CHRONO_HAS_LOAD_HYDRODYNAMICS)
+    message(STATUS "ChLoadHydrodynamics not found in Chrono -- using legacy added-mass implementation")
+endif()
+
 # Enable Irrlicht support if requested and available
 if(HYDROCHRONO_ENABLE_IRRLICHT AND NOT TARGET Chrono::Chrono_irrlicht)
   message(FATAL_ERROR "HYDROCHRONO_ENABLE_IRRLICHT is ON but Chrono::Chrono_irrlicht target not found. Ensure Chrono was built with Irrlicht support.")
@@ -239,7 +280,49 @@ endif()
 find_package(OpenMP REQUIRED COMPONENTS CXX)
 
 # -- HDF5 Integration --
-find_package(HDF5 REQUIRED COMPONENTS CXX)
+# Config-mode discovery runs early (before Chrono) to avoid target conflicts
+# with the hdf5_tools shims. Fall back to module-mode here if it wasn't found.
+if(NOT HDF5_FOUND)
+    find_package(HDF5 REQUIRED COMPONENTS CXX)
+endif()
+
+# -- MoorDyn mooring library (optional) --
+if(HYDROCHRONO_ENABLE_MOORDYN)
+    message(STATUS "\n---- MoorDyn mooring library")
+    if(NOT EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/extern/MoorDyn/CMakeLists.txt")
+        message(FATAL_ERROR
+            "MoorDyn submodule not found at extern/MoorDyn.\n"
+            "Run:  git submodule update --init extern/MoorDyn")
+    endif()
+    # MoorDyn's CMakeLists.txt uses CMAKE_SOURCE_DIR (which resolves to
+    # HydroChrono's root) for its config template and CPack license.
+    # Copy the files it expects so the configure step succeeds.
+    if(NOT EXISTS "${CMAKE_SOURCE_DIR}/cmake/MoorDynConfig.cmake")
+        file(COPY "${CMAKE_CURRENT_SOURCE_DIR}/extern/MoorDyn/cmake/MoorDynConfig.cmake"
+             DESTINATION "${CMAKE_SOURCE_DIR}/cmake/")
+    endif()
+    if(NOT EXISTS "${CMAKE_SOURCE_DIR}/LICENSE.txt")
+        file(COPY "${CMAKE_CURRENT_SOURCE_DIR}/extern/MoorDyn/LICENSE.txt"
+             DESTINATION "${CMAKE_SOURCE_DIR}/")
+    endif()
+
+    set(EXTERNAL_EIGEN OFF CACHE BOOL "Use MoorDyn bundled Eigen" FORCE)
+    set(PYTHON_WRAPPER OFF CACHE BOOL "Disable MoorDyn Python wrapper" FORCE)
+    set(FORTRAN_WRAPPER OFF CACHE BOOL "Disable MoorDyn Fortran wrapper" FORCE)
+    set(MATLAB_WRAPPER OFF CACHE BOOL "Disable MoorDyn MATLAB wrapper" FORCE)
+    set(RUST_WRAPPER OFF CACHE BOOL "Disable MoorDyn Rust wrapper" FORCE)
+    set(BUILD_TESTING_SAVED ${BUILD_TESTING})
+    set(BUILD_TESTING OFF)
+    add_subdirectory(extern/MoorDyn)
+    set(BUILD_TESTING ${BUILD_TESTING_SAVED})
+    # MoorDyn is a shared library (DLL) -- its internal Eigen usage must not
+    # leak into HydroChrono's include paths (HydroChrono uses Chrono's Eigen).
+    set_target_properties(moordyn PROPERTIES
+        INTERFACE_INCLUDE_DIRECTORIES ""
+    )
+    message(STATUS "MoorDyn mooring coupling: ENABLED")
+    message(STATUS "----\n")
+endif()
 
 # ===============================================================================
 # ----- Create HydroChrono configuration header ---------------------------------
@@ -261,6 +344,12 @@ else()
   set(HC_HAS_VSG "#undef HYDROCHRONO_HAVE_VSG")
 endif()
 
+if(HYDROCHRONO_ENABLE_MOORDYN)
+  set(HC_HAS_MOORDYN "#define HYDROCHRONO_HAVE_MOORDYN")
+else()
+  set(HC_HAS_MOORDYN "#undef HYDROCHRONO_HAVE_MOORDYN")
+endif()
+
 # For BUILD tree
 set(HC_DATA_DIR "#define HC_DATA_DIR \"${HC_BUILD_DATA}\"")
 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake/config.h.in
@@ -317,13 +406,41 @@ set(HC_SOURCES
     src/hydro/logging/logging.cpp
 )
 
+# MoorDyn mooring sources (conditionally compiled).
+# The wrapper is built as a separate OBJECT library so that MoorDyn's
+# bundled Eigen headers stay isolated and don't conflict with the
+# system/Chrono Eigen used by HydroChrono.
+if(HYDROCHRONO_ENABLE_MOORDYN)
+    add_library(moordyn_bridge OBJECT
+        src/hydro/mooring/moordyn_wrapper.cpp
+    )
+    target_include_directories(moordyn_bridge PRIVATE
+        "${CMAKE_CURRENT_SOURCE_DIR}/extern/MoorDyn/source"
+        "${CMAKE_CURRENT_SOURCE_DIR}"
+        "${CMAKE_CURRENT_SOURCE_DIR}/include"
+    )
+    target_link_libraries(moordyn_bridge PRIVATE moordyn)
+    target_compile_features(moordyn_bridge PUBLIC cxx_std_17)
+    # Pick up HydroChrono's public headers (system_state.h, hydro_types.h)
+    target_include_directories(moordyn_bridge PUBLIC
+        "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>"
+    )
+    # Chrono headers needed for Eigen (used by hydro_types.h)
+    target_link_libraries(moordyn_bridge PUBLIC Chrono::Chrono_core)
+
+    list(APPEND HC_SOURCES
+        src/hydro/force_components/mooring_component.cpp
+    )
+endif()
+
 set(HC_HEADERS
     ${PROJECT_BINARY_DIR}/hydroc/config.h
     ${PROJECT_BINARY_DIR}/hydroc/version.h
     include/hydroc/hydro_system.h
     include/hydroc/helper.h
     include/hydroc/logging.h
     include/hydroc/config/hydro_config.h
+    include/hydroc/config/moordyn_config.h
     include/hydroc/core/force_component.h
     include/hydroc/core/hydro_forces.h
     include/hydroc/core/hydro_types.h
@@ -361,19 +478,23 @@ if(TARGET hdf5::hdf5-static)
   target_link_libraries(HydroChrono PUBLIC hdf5::hdf5_cpp-static)
   target_link_libraries(HydroChrono PUBLIC hdf5::hdf5_hl-static)
   target_link_libraries(HydroChrono PUBLIC hdf5::hdf5_hl_cpp-static)
-  target_link_libraries(HydroChrono PUBLIC hdf5::hdf5_tools-static)
+  if(TARGET hdf5::hdf5_tools-static)
+    target_link_libraries(HydroChrono PUBLIC hdf5::hdf5_tools-static)
+  endif()
 elseif(TARGET hdf5::hdf5-shared)
   message(STATUS "Linking shared libraries hdf5::hdf5-shared")
   target_link_libraries(HydroChrono PUBLIC hdf5::hdf5-shared)
   target_link_libraries(HydroChrono PUBLIC hdf5::hdf5_cpp-shared)
   target_link_libraries(HydroChrono PUBLIC hdf5::hdf5_hl-shared)
   target_link_libraries(HydroChrono PUBLIC hdf5::hdf5_hl_cpp-shared)
-  target_link_libraries(HydroChrono PUBLIC hdf5::hdf5_tools-shared)
   list(APPEND HDF5_TARGETS hdf5::hdf5-shared)
   list(APPEND HDF5_TARGETS hdf5::hdf5_cpp-shared)
   list(APPEND HDF5_TARGETS hdf5::hdf5_hl-shared)
   list(APPEND HDF5_TARGETS hdf5::hdf5_hl_cpp-shared)
-  list(APPEND HDF5_TARGETS hdf5::hdf5_tools-shared)
+  if(TARGET hdf5::hdf5_tools-shared)
+    target_link_libraries(HydroChrono PUBLIC hdf5::hdf5_tools-shared)
+    list(APPEND HDF5_TARGETS hdf5::hdf5_tools-shared)
+  endif()
 elseif(TARGET HDF5::HDF5)
   message(STATUS "Linking HDF5::HDF5")
   target_link_libraries(HydroChrono PUBLIC HDF5::HDF5)
@@ -391,11 +512,21 @@ target_include_directories(HydroChrono
     ${CMAKE_CURRENT_SOURCE_DIR}/include
 )
 
+# Add MoorDyn (optional mooring coupling)
+if(HYDROCHRONO_ENABLE_MOORDYN AND TARGET moordyn)
+    # Link moordyn import lib for DLL binding; moordyn_bridge provides
+    # the compiled wrapper objects with MoorDyn headers isolated from HC.
+    target_link_libraries(HydroChrono PRIVATE $<TARGET_LINKER_FILE:moordyn>)
+    target_sources(HydroChrono PRIVATE $<TARGET_OBJECTS:moordyn_bridge>)
+    target_compile_definitions(HydroChrono PUBLIC HYDROCHRONO_HAVE_MOORDYN)
+endif()
+
 # Library-specific compile definitions
 target_compile_definitions(HydroChrono
     PUBLIC
         "HYDROCHRONO_VERSION=\"${PROJECT_VERSION}\""
         "HYDROCHRONO_BUILD_TYPE=\"$<IF:$<CONFIG:Debug>,Debug,$<IF:$<CONFIG:Release>,Release,$<IF:$<CONFIG:RelWithDebInfo>,RelWithDebInfo,$<IF:$<CONFIG:MinSizeRel>,MinSizeRel,Unknown>>>>\""
+        $<$<NOT:$<BOOL:${CHRONO_HAS_LOAD_HYDRODYNAMICS}>>:HYDROCHRONO_USE_LEGACY_ADDED_MASS>
     PRIVATE 
         $<$<BOOL:${HYDROCHRONO_ENABLE_LOGGING}>:HYDROCHRONO_ENABLE_LOGGING="1">
 )
@@ -425,6 +556,7 @@ if(HYDROCHRONO_ENABLE_VSG)
       src/gui/vsg_gui_component.cpp
       src/gui/vsg_lighting.cpp
       src/gui/vsg_materials.cpp
+      src/gui/vsg_mooring_lines.cpp
       src/gui/vsg_water_surface.cpp
       src/gui/vsg_radiation_surface.cpp
   )
@@ -433,6 +565,7 @@ if(HYDROCHRONO_ENABLE_VSG)
       src/gui/vsg_gui_component.h
       src/gui/vsg_lighting.h
       src/gui/vsg_materials.h
+      src/gui/vsg_mooring_lines.h
       src/gui/vsg_water_surface.h
       src/gui/vsg_radiation_surface.h
   )
@@ -515,6 +648,12 @@ function(configure_test_environment)
         list(APPEND DLL_DIRS ${VSG_DLL_DIR})
     endif()
 
+    # MoorDyn DLL path
+    if(HYDROCHRONO_ENABLE_MOORDYN AND TARGET moordyn)
+        list(APPEND DLL_DIRS "$<TARGET_FILE_DIR:moordyn>")
+        message(STATUS "  MoorDyn DLL directory:            (via target)")
+    endif()
+
     set(TEST_ENVIRONMENT "PATH=${DLL_DIRS};$ENV{PATH}" PARENT_SCOPE)
 endfunction()
 
@@ -547,6 +686,7 @@ if(HYDROCHRONO_ENABLE_TESTS)
     endif()
 
     add_subdirectory(tests/regression)
+    add_subdirectory(tests/verification)
     add_subdirectory(tests/unit)
 endif()
 
@@ -715,6 +855,21 @@ if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
         endforeach()
     endif()
 
+    # MoorDyn DLL
+    if(HYDROCHRONO_ENABLE_MOORDYN AND TARGET moordyn)
+        install(TARGETS moordyn
+            CONFIGURATIONS Release
+            RUNTIME DESTINATION bin COMPONENT runtime)
+        message(STATUS "  MoorDyn DLL (via target)")
+    endif()
+
+endif()
+
+# MoorDyn license bundling
+if(HYDROCHRONO_ENABLE_MOORDYN)
+    install(FILES "${CMAKE_SOURCE_DIR}/extern/MoorDyn/LICENSE.txt"
+            RENAME MoorDyn_LICENSE.txt
+            DESTINATION licenses COMPONENT runtime)
 endif()
 
 # Public, user-facing regression test suite only
@@ -750,6 +905,13 @@ if(MSVC AND OpenMP_CXX_FOUND)
     endif()
 endif()
 include(InstallRequiredSystemLibraries)
+
+# Third-party license notices
+if(EXISTS "${CMAKE_SOURCE_DIR}/THIRD_PARTY_NOTICES.txt")
+    install(FILES "${CMAKE_SOURCE_DIR}/THIRD_PARTY_NOTICES.txt"
+            DESTINATION . COMPONENT runtime)
+endif()
+
 set(CPACK_GENERATOR "ZIP")
 set(CPACK_PACKAGE_NAME "HydroChrono")
 set(CPACK_COMPONENTS_ALL runtime python-tests dev-demos)

THIRD_PARTY_NOTICES.txt

@@ -0,0 +1,40 @@
+THIRD-PARTY SOFTWARE NOTICES AND INFORMATION
+
+HydroChrono incorporates third-party components under the licenses listed below.
+The original license files are included in the licenses/ directory of this
+distribution.
+
+================================================================================
+MoorDyn v2.6.1
+https://github.com/FloatingArrayDesign/MoorDyn
+License: BSD 3-Clause
+License file: licenses/MoorDyn_LICENSE.txt
+
+Copyright (c) 2022, Matt Hall
+All rights reserved.
+
+Redistribution and use in source and binary forms, with or without modification,
+are permitted provided that the following conditions are met:
+
+1. Redistributions of source code must retain the above copyright notice, this
+   list of conditions and the following disclaimer.
+
+2. Redistributions in binary form must reproduce the above copyright notice,
+   this list of conditions and the following disclaimer in the documentation
+   and/or other materials provided with the distribution.
+
+3. Neither the name of the copyright holder nor the names of its contributors
+   may be used to endorse or promote products derived from this software without
+   specific prior written permission.
+
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR
+ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
+(INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
+ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+(INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+================================================================================