Helios/build.gradle at main · HTTP-RPC/Helios · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
plugins {
    id 'application'
    id 'org.gradlex.extra-java-module-info' version '1.14.2'
}

repositories {
    mavenCentral()
    mavenLocal()
}

dependencies {
    implementation "org.httprpc:sierra:${sierraVersion}"
    implementation "com.formdev:flatlaf:${flatLafVersion}"
    implementation "org.xerial:sqlite-jdbc:${sqliteJDBCVersion}"
    implementation "net.jthink:jaudiotagger:${jAudioTaggerVersion}"
    implementation "net.java.dev.jna:jna-platform-jpms:${jnaVersion}"
}

extraJavaModuleInfo {
    module('net.jthink:jaudiotagger', 'org.jaudiotagger') {
        requires 'java.desktop'
        requires 'java.datatransfer'
        requires 'java.logging'

        exports 'org.jaudiotagger.audio'
        exports 'org.jaudiotagger.audio.exceptions'
        exports 'org.jaudiotagger.tag'
        exports 'org.jaudiotagger.tag.images'
    }
}

compileJava {
    options.headerOutputDirectory = "${projectDir}/src/main/jni/include"
}

tasks.withType(JavaCompile).configureEach {
    options.compilerArgs = [
        '-parameters'
    ]
}

application {
    applicationName = 'Helios'

    mainModule = 'org.httprpc.helios'
    mainClass = 'org.httprpc.helios.Helios'
}

version = '1.0.6'

tasks.register("buildMacOS", Exec) {
    executable = 'bin/build-macos.sh'
}

tasks.register("packageMacOS", Exec) {
    executable = 'jpackage'

    args = [
        '--name', "${application.applicationName}",
        '--vendor', 'httprpc.org',
        '--module', "${application.mainModule.get()}/${application.mainClass.get()}",
        '--module-path', "${configurations.runtimeClasspath.asPath}:build/libs",
        '--java-options', '--enable-native-access=org.httprpc.helios,com.formdev.flatlaf,org.xerial.sqlitejdbc,com.sun.jna',
        '--app-version', "${version}"
    ]

    if (System.getProperty("os.arch").equalsIgnoreCase("aarch64")) {
        args += [
            '--mac-sign',
            '--mac-signing-key-user-name', System.getenv('MAC_SIGNING_KEY_USER_NAME')
        ]
    }
}

tasks.register("notarizeMacOS", Exec) {
    dependsOn 'packageMacOS'

    executable = 'xcrun'

    args = [
        'notarytool', 'submit',
        '--apple-id', System.getenv('NOTARY_TOOL_APPLE_ID'),
        '--team-id', System.getenv('NOTARY_TOOL_TEAM_ID'),
        '--password', System.getenv('NOTARY_TOOL_PASSWORD'),
        '--wait', "${application.applicationName}-${version}.dmg"
    ]
}

tasks.register("stapleMacOS", Exec) {
    dependsOn 'notarizeMacOS'

    executable = 'stapler'

    args = ['staple', "${application.applicationName}-${version}.dmg"]
}

tasks.register("buildWindows", Exec) {
    executable = 'bin/build-windows.bat'
}

tasks.register("packageWindows", Exec) {
    executable = 'jpackage'

    args = [
        '--name', "${application.applicationName}",
        '--vendor', 'httprpc.org',
        '--module', "${application.mainModule.get()}/${application.mainClass.get()}",
        '--module-path', "${configurations.runtimeClasspath.asPath};build/libs",
        '--java-options', '--enable-native-access=org.httprpc.helios,com.formdev.flatlaf,org.xerial.sqlitejdbc,com.sun.jna',
        '--app-version', "${version}",
        '--win-shortcut'
    ]
}

tasks.register("prepareWindows", Exec) {
    dependsOn 'packageWindows'

    executable = 'attrib'

    args = [
        '-r', "${application.applicationName}-${version}.exe"
    ]
}

tasks.register("signWindows", Exec) {
    dependsOn 'prepareWindows'

    executable = 'signtool'

    args = [
        'sign',
        '/f', System.getenv('SIGNTOOL_CERTIFICATE'),
        '/p', System.getenv('SIGNTOOL_PASSWORD'),
        '/d', "${application.applicationName}",
        '/fd', 'SHA256',
        '/tr', 'http://timestamp.digicert.com',
        '/td', 'SHA256',
        "${application.applicationName}-${version}.exe"
    ]
}