flicknote-cli/flake.nix at main · GuionAI/flicknote-cli · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
{
  description = "FlickNote CLI — local-first note management with cloud sync";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs = { self, nixpkgs, flake-utils, rust-overlay }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs { inherit system overlays; };

        rust = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;

        nativeBuildInputs = with pkgs; [
          rust
          pkg-config
          llvmPackages.libclang
          sqlite
        ];

        buildInputs = with pkgs; [
          cacert
          openssl
          sqlite
        ] ++ lib.optionals stdenv.isDarwin [
          darwin.apple_sdk.frameworks.Security
          darwin.apple_sdk.frameworks.SystemConfiguration
        ];

        flicknote = pkgs.rustPlatform.buildRustPackage {
          pname = "flicknote";
          version = (builtins.fromTOML (builtins.readFile ./Cargo.toml)).workspace.package.version;

          src = ./.;
          cargoLock = {
            lockFile = ./Cargo.lock;
            outputHashes = {
              "powersync-0.0.7" = "sha256-Ndeu/7054EsfgVHQwu0W7CjbjT1q/e15qX2V3A0XihA=";
            };
          };

          nativeBuildInputs = nativeBuildInputs;
          buildInputs = buildInputs;
          LIBCLANG_PATH = "${pkgs.llvmPackages.libclang.lib}/lib";
          SSL_CERT_FILE = "${pkgs.cacert}/etc/ssl/certs/ca-bundle.crt";

          meta = with pkgs.lib; {
            description = "Local-first note management CLI with cloud sync";
            homepage = "https://github.com/GuionAI/flicknote-cli";
            license = licenses.mit;
            mainProgram = "flicknote";
          };
        };

      in
      {
        packages = {
          default = flicknote;
          flicknote = flicknote;
        };

        devShells.default = pkgs.mkShell {
          inherit nativeBuildInputs buildInputs;
          LIBCLANG_PATH = "${pkgs.llvmPackages.libclang.lib}/lib";
          SSL_CERT_FILE = "${pkgs.cacert}/etc/ssl/certs/ca-bundle.crt";

          shellHook = ''
            echo "flicknote-cli dev shell (rust $(rustc --version | cut -d' ' -f2))"
          '';
        };
      });
}