ObjectSizeProof/all.bat at master · ComboxSoftDeveloper/ObjectSizeProof · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
@echo off
chcp 866 >nul
setlocal enabledelayedexpansion

rem ‚¥áì ¯à®£® ®¤®© ª®¬ ¤®©. ‘ª« ¤ë¢ ¥â ¢áñ ¢ Results\<¨¬ï ¬ è¨ë>.

rem BenchmarkDotNet á®¡¨à ¥â ¢á¯®¬®£ â¥«ìë© ¯à®¥ªâ ¨ ¯¥à¥¤ ñâ ¯ãâì ¢ MSBuild
rem ¡¥§ ª ¢ëç¥ª. ‡ ¯ïâ ï ¨ â®çª  á § ¯ïâ®© ¢ ¯ãâ¨ à §¡¨à îâáï ª ª à §¤¥«¨â¥«¨
rem á¯¨áª  á¢®©áâ¢, á¡®àª  ¯ ¤ ¥â á MSB1006, ¨ § ¬¥àë ¥ ¢ë¯®«ïîâáï ¢®¢á¥.
rem Žâçñâë ¯à¨ íâ®¬ á¨¬ îâáï ®à¬ «ì®, ¯®íâ®¬ã á¡®© «¥£ª® ¥ § ¬¥â¨âì.
set "PATHCHK=%CD%"
if not "%PATHCHK%"=="%PATHCHK:,=%" goto badpath
if not "%PATHCHK%"=="%PATHCHK:;=%" goto badpath

set NAME=%COMPUTERNAME%
set OUT=Results\%NAME%
if not exist "Results" mkdir "Results"
if not exist "%OUT%" mkdir "%OUT%"
if not exist "%OUT%" (
    echo ¥ ã¤ «®áì á®§¤ âì ¯ ¯ªã %OUT%
    goto fail
)

if exist "Bdn\*.log" del /Q "Bdn\*.log"

echo ‚áñ «ï¦¥â ¢ %OUT%
echo.

echo === ‘¡®àª  ===
dotnet build -c Release -warnaserror
if errorlevel 1 goto fail

echo.
echo === ‘¢¥àª    âàñå à â ©¬ å ===
for %%T in (net8.0 net9.0 net10.0) do (
    echo   %%T
    dotnet run -c Release -f %%T --no-build -- checks > "%OUT%\checks_%%T.txt"
    if errorlevel 1 (
        echo ‘¢¥àª  ¥ ¯à®è«    %%T, á¬®âà¨ "%OUT%\checks_%%T.txt"
        goto fail
    )
)

echo.
echo === Žâçñâë ===
for %%T in (net8.0 net9.0 net10.0) do (
    for %%R in (sizes layout header) do (
        echo   %%T %%R
        dotnet run -c Release -f %%T --no-build -- %%R > "%OUT%\%%R_%%T.txt"
    )
)

rem  §¬¥à ®¡ê¥ªâ  ®â  áâà®¥ª á¡®àé¨ª  ¥ § ¢¨á¨â,   ¢®â ®¡å®¤ ¬ áá¨¢
rem áâàãªâãà ã¯¨à ¥âáï ¢ ¯ ¬ïâì, ¯®íâ®¬ã á¥à¢¥àë© á¡®àé¨ª ¯à®¢¥àï¥âáï â®¦¥.
echo.
echo ===   á¥à¢¥à®¬ á¡®àé¨ª¥ ===
set DOTNET_gcServer=1
for %%T in (net8.0 net9.0 net10.0) do (
    echo   %%T
    dotnet run -c Release -f %%T --no-build -- sizes > "%OUT%\sizes_%%T_servergc.txt"
)
set DOTNET_gcServer=

echo.
echo === à®¡ : ®¤¨ ª« áá ¡¥§ ¤¨§ áá¥¬¡«¥à  ===
dotnet run -c Release -f net10.0 --no-build -- --filter *CreateBench* noasm > "%OUT%\probe_noasm.txt" 2>&1
set PROBE1=%ERRORLEVEL%
if exist "Bdn\ObjectSizeProof.log" copy /Y "Bdn\ObjectSizeProof.log" "%OUT%\probe_noasm.log" >nul
if exist "Bdn\*.log" del /Q "Bdn\*.log"
if not "%PROBE1%"=="0" echo   § ¢¥àè¨«®áì á ®è¨¡ª®©, á¬®âà¨ "%OUT%\probe_noasm.txt"

echo.
echo === à®¡ : ®¤¨ ª« áá á ¤¨§ áá¥¬¡«¥à®¬ ===
dotnet run -c Release -f net10.0 --no-build -- --filter *CreateBench* > "%OUT%\probe_asm.txt" 2>&1
set PROBE2=%ERRORLEVEL%
if exist "Bdn\ObjectSizeProof.log" copy /Y "Bdn\ObjectSizeProof.log" "%OUT%\probe_asm.log" >nul
if exist "Bdn\*.log" del /Q "Bdn\*.log"
if not "%PROBE2%"=="0" echo   § ¢¥àè¨«®áì á ®è¨¡ª®©, á¬®âà¨ "%OUT%\probe_asm.txt"

echo.
echo === ‡ ¬¥àë   âàñå à â ©¬ å ®¤¨¬ § ¯ãáª®¬ ===
dotnet run -c Release -f net10.0 --no-build -- --filter *
set MAIN=%ERRORLEVEL%

if exist "Bdn\ObjectSizeProof.log" copy /Y "Bdn\ObjectSizeProof.log" "%OUT%\bench.log" >nul

if exist "Bdn\results" (
    if not exist "%OUT%\bench" mkdir "%OUT%\bench"
    xcopy /Y /E /I "Bdn\results" "%OUT%\bench" >nul
)

echo.
if not "%MAIN%"=="0" (
    echo ‡ ¬¥àë § ¢¥àè¨«¨áì á ®è¨¡ª®©. à¨ç¨  ¢ "%OUT%\bench.log".
    goto fail
)

echo ƒ®â®¢®. ‚áñ «¥¦¨â ¢ %OUT%
goto end

:badpath
echo.
echo ‚ ¯ãâ¨ ª ¯à®¥ªâã ¥áâì § ¯ïâ ï ¨«¨ â®çª  á § ¯ïâ®©:
echo %CD%
echo.
echo BenchmarkDotNet ¥ á®¡¥àñâ ¢á¯®¬®£ â¥«ìë© ¯à®¥ªâ ¢ â ª®¬ ¯ãâ¨.
echo ¥à¥¥áâ¨ ¯à®¥ªâ âã¤ , £¤¥ íâ¨å § ª®¢ ¥â, ¨ § ¯ãáâ¨âì á®¢ .
endlocal
exit /b 1

:fail
echo.
echo à®£® ®áâ ®¢«¥.
endlocal
exit /b 1

:end
endlocal