all.bat

@echo off
cd /d %~dp0
setlocal

rem Ves progon odnoy komandoy. Zapuskat bez argumentov.

set NAME=%~1
if "%NAME%"=="" set NAME=%COMPUTERNAME%
set OUT=Results\%NAME%
if not exist "%OUT%" mkdir "%OUT%"

echo ==========================================================
echo  DivRemProof
echo  Mashina: %NAME%
echo  Rezultaty: %OUT%
echo ==========================================================
echo.

where dotnet >nul 2>&1
if errorlevel 1 goto nodotnet

echo [1/4] Build i chistka proshlogo progona
del /q checks-*.txt 2>nul
rmdir /s /q BenchmarkDotNet.Artifacts 2>nul
dotnet build -c Release > "%OUT%\build.txt" 2>&1
if errorlevel 1 goto buildfail
echo       ok
echo.

echo [2/4] Sverka otvetov na treh runtaymah
for %%R in (net8.0 net9.0 net10.0) do (
  dotnet run -c Release -f %%R --no-build -- checks > "%OUT%\checks-%%R.txt" 2>&1
  if errorlevel 1 goto checksfail
)
echo       ok
echo.

echo [3/4] Zamery. Okolo 40 minut, 4 klassa
dotnet run -c Release -f net10.0 --no-build
if errorlevel 1 goto benchfail
echo       ok
echo.

echo [4/4] Sbor rezultatov v %OUT%
if exist BenchmarkDotNet.Artifacts\results (
  if not exist "%OUT%\bench" mkdir "%OUT%\bench"
  xcopy /y /q BenchmarkDotNet.Artifacts\results\*.* "%OUT%\bench\" > nul
  copy /y BenchmarkDotNet.Artifacts\*.log "%OUT%\bench\" > nul 2>&1
)
dotnet --info > "%OUT%\environment.txt" 2>&1
echo       ok
echo.

echo Gotovo. Vsyo lezhit v %OUT%
echo Listingi mashinnogo koda snimayutsya otdelno: Disasm\snap.bat
pause
exit /b 0

:nodotnet
echo DOTNET NE NAYDEN. Ustanovit SDK .NET 8, 9 i 10.
pause
exit /b 1

:buildfail
echo BUILD NE PROSHEL. Smotret %OUT%\build.txt
pause
exit /b 1

:checksfail
echo SVERKA OTVETOV NE PROSHLA. Smotret %OUT%\checks-*.txt
pause
exit /b 1

:benchfail
echo ZAMERY NE PROSHLI.
pause
exit /b 1